###############################################################################
# HSPACE: Simulator Pod System.  Written by Allan Taylor (Allant@tis.com.au)  #
###############################################################################
#
# SIMULATOR_UNIVERSE This should be changed on the child only! The Parent
#                    Default is the same universe that matches the room that it
#                    is in.
#
# PARENT_POD should be changed to an object that will act as a parent to the
#            sim pods. This is used for checking the validity of a pod for
#            loading. And for basic desc's.
#
# TEMPLATE_CLASSES This is a list of SHIP DB Numbers that will act as templates
#                  To the simulator system. These ships will be duplicated onto
#		   the sim pod when loaded.
#
# @sim/new pod <number of pods>		'Creates a new pod with X consoles
# load pod <ID>=<TEMPLATE>		'Loads a pod with template class
# unload pod <ID>			'Self explanitory
#
###############################################################################
# THIS IS BETA CODE AND HAS NOT BEEN FULLY TESTED. SUPPORT IS AVAILABLE BY
# EMAILING ALLANT@TIS.COM.AU
###############################################################################

@create $Parent: Simulator Control Panel

&PARENT_POD $Parent: Simulator Control Panel=#119

&CMD_LOADPOD $Parent: Simulator Control Panel=$load pod *=*:@switch [switch(member(u(TEMPLATE_CLASSES),setr(t,#[%1])),0,[pemit(%#,ansi(yh,WARNING: Invalid Class))]0,1)][switch(member(parent(#[%0]),u(PARENT_POD)),0,[pemit(%#,ansi(yh,WARNING: Invalid Simulator Pod))]0,1)])][switch(loc(me),loc(#[%0]),1,0[pemit(%#,ansi(yh,WARNING: Simulator Pod must be local!))])]=*0*,@pemit %#=[ansi(rh,ERROR: Unable to load pod. Aborting....)],{@pemit %#=[ansi(gh,SIMULATOR: Loading pod %0. Please Wait.....)];@tr me/PROG_LOADPOD=#[%0],#[%1],%#}

&CMD_NEWPOD $Parent: Simulator Control Panel=$@sim/new pod *:[switch(hasflag(%#,Wizard),0,[pemit(%#,ansi(rh,SIMULATOR: Command restricted to wizards.))],[setq(p,create([rand(100000)]))][name(r(p),Simulator Pod ID:[mid(r(p),1,sub(strlen(r(p)),1))])][tel(r(p),loc(me))][parent(r(p),u(PARENT_POD))][iter(lnum(%0),[setq(c,create(Console ##))][set(r(c),wizard)][set(r(c),!no_command)][lock(r(p),r(p))][tel(r(c),r(p))][set(r(p),CONSOLES:[u(r(p)/CONSOLES)]%b[r(c)])])][pemit(%#,ansi(gh,SIMULATOR: Pod Created))]

&CMD_UNLOADPOD $Parent: Simulator Control Panel=$unload pod *:@switch [switch(member(parent(#[%0]),u(PARENT_POD)),0,[pemit(%#,ansi(yh,WARNING: Invalid Simulator Pod))]0,1)])][switch(loc(me),loc(#[%0]),1,0[pemit(%#,ansi(yh,WARNING: Simulator Pod must be local!))])]=*0*,@pemit %#=[ansi(rh,ERROR: Unable to unload pod. Aborting....)],{@pemit %#=[ansi(gh,SIMULATOR: unLoading pod %0.)];@space/mothball #[%0]}

&FN_LOADWEAPON $Parent: Simulator Control Panel=[repeat(hs_del_weapon(%0,1),15)][pemit(%2,ansi(gh,SIMULATOR: Clearing Old Weapons -- OK))][iter(hs_get_Attr(%1,weapons),[hs_add_Weapon(%0,##)][pemit(%2,ansi(gh,SIMULATOR: Adding weapon ## -- OK))][switch(hs_weapon_attr(##,type),1,[hs_set_missile(u(%0/HSDB_OWNER),##,[extract([hs_get_missile(u(%1/HSDB_OWNER),##)],2,1,/)])][pemit(%2,ansi(gh,SIMULATOR: Ammunition loading for weapon ## -- OK))])])]

&PROG_LOADCONSOLES $Parent: Simulator Control Panel=th [hs_sysset(%0/fuel system,burnable fuel:[hs_sys_attr(%0/fuel system,max burnable fuel,0)])][pemit(%2,ansi(gh,SIMULATOR: Refueling Virtual Ship BURNABLE -- OK))][hs_sysset(%0/fuel system,reactable fuel:[hs_sys_attr(%0/fuel system,max reactable fuel,0)])][pemit(%2,ansi(gh,SIMULATOR: Refueling Virtual Ship REACTABLE -- OK))];@dolist %3={@space/addconsole %0=[extract(u(%0/CONSOLES),#@,1)];th [pemit(%2,ansi(gh,SIMULATOR: Loading Console #@ -- OK))];@wait 1=th [parent(extract(u(%0/CONSOLES),#@,1),parent(##))][u(FN_LOADWEAPON,extract(u(%0/CONSOLES),#@,1),##,%2)]}

&PROG_LOADPOD $Parent: Simulator Control Panel=@switch [setq(t,hs_get_attr(%1,class))][setq(c,hs_get_attr(%1,consoles))][switch(words(r(c)),words(u(%0/CONSOLES)),1,[gt(words(u(%0/CONSOLES)),words(r(c)))])]=0,@pemit %2=[ansi(rh,SIMULATOR: Console Match Check -- FAIL(ABORTING))],{@pemit %2=[ansi(gh,SIMULATOR: Console Match Check -- OK)];@space/mothball %0;@space/activate %0=[r(t)];@pemit %2=[ansi(gh,SIMULATOR: Loading Class -- OK)];@wait 1={@tr me/PROG_LOADCONSOLES=%0,%1,%2,r(c);@space/set %0/UID=[u(SIMULATOR_UNIVERSE)]}

&TEMPLATE_CLASSES $Parent: Simulator Control Panel=[iter(lattr(#97/TEMPLATE_*),u(#97/##))]

&SIMULATOR_UNIVERSE $Parent: Simulator Control Panel=[mid(loc(me),1,99)]