#    Unknown
#    Format: Ellan West (12/30/96)
#
######################################################################################
#
#  This cutie was coded by a player who used to be on both Pernmush and Soucon...
#  I confess, I used to remember these things. It was donated to the Soucon
#  Harperhall while I was Craftmaster Elizabeth, so here... if you can id the
#  source, please let me know.  
#
#####################################################################################
#
# CONFIGURATION
#  None, just create it, and read the instructions. The text phrases can be edited
#  to suggest a setting closer to your theme. The first place I saw it, the
#  text was very salty and seaworthy.. a rowdy pirate attitude. This version
#  is the only one I have left.
#
#####################################################################################
@create Songkeg=1
-
@Desc Songkeg=A keg full of ale, about which people are gathered. 
     They seem about to burst into song... Type 'Use [name(me)]' for help.
-
@Use Songkeg=This keg can be used to sing a song, usually to poke good-natured, 
     often sarcastic fun at someone's stronger personality traits...%r To write a verse, 
     type "kegsing <line1>//<line2>".%r%r For instance:%r kegsing I saw a Sailor with 
     nothing to do//Well, maybe just a thing or two! %r%r Will produce the verse: %r%t%tI 
     saw a Sailor with nothing to do%r%t%t(Fie, man, Fie!)%r%t%tI saw a Sailor with nothing 
     to do%r%t%t(Who's the fool, now?)%r%t%tI saw a Sailor with nothing to do%r%t%tWell, 
     maybe jus t a thing or two!%r%t%t(Hush, you've well drunken, man, Who's the fool now!?)
-
@Ouse Songkeg=carefully studies the [v(feature[rand(4)])] on the keg.
-
&FEATURE0 Songkeg=spigot
-
&FEATURE1 Songkeg=markings
-
&FEATURE2 Songkeg=staves
-
&FEATURE3 Songkeg=braces
-
&C-SING Songkeg=$kegsing *//*:@wait me/[v(d-timer)]=@tr 
    me/s-verse=%#,%0,%1;@pemit owner(%#)=Your verse is waiting to play, 
    and will do so [u(f-delaymsg[v(d-state)])];@switch 
    lt(add(v(semaphore),v(d-state)),v(d-startverse))=0,{@notify me;&d-state me=-999}
-
&D-PREFNUM Songkeg=8
-
&D-PREF0 Songkeg=coughs, to clear the throat
-
&D-PREF1 Songkeg=grins wickedly
-
&D-PREF2 Songkeg=draws a long breath
-
&D-PREF3 Songkeg=looks around the room
-
&D-PREF4 Songkeg=takes a step forward
-
&D-PREF5 Songkeg=notes a momentary pause
-
&D-PREF6 Songkeg=takes advantage of a lull
-
&D-PREF7 Songkeg=nods to a friend
-
&D-VERBNUM Songkeg=4
-
&D-VERB0 Songkeg=belts out
-
&D-VERB1 Songkeg=sings
-
&D-VERB2 Songkeg=silences the crowd
-
&D-VERB3 Songkeg=leans on the keg for support
-
&D-DELAY Songkeg=3
-
&S-VERSE Songkeg=@emit name(owner(%0)) [s(v(d-pref[rand(v(d-prefnum))]))], and 
     [s(v(d-verb[rand(v(d-verbnum))]))]:%r%t%t%1;@wait [v(d-delay)]=@emit The crowd sings 
     back: %tFie, man, Fie!;@wait [mul(v(d-delay),2)]=@emit name(owner(%0)) emphatically 
     repeats:%r%t%t%1;@wait [mul(v(d-delay),3)]=@emit The crowd exclaims: %tWho's the fool 
     now?;@wait [mul(v(d-delay),4)]=@emit name(owner(%0)) 
     [s(v(d-pref[rand(v(d-prefnum))]))], 
     and [s(v(d-verb[rand(v(d-verbnum))]))]:%r%t%t%1;@wait [mul(v(d-delay),5)]=@emit %t%t%2;
     @wait [mul(v(d-delay),6)]=@emit The crowd choruses in response:%r%t%tHush, you've well 
     drunken, man, who's the fool now?!%r;@wait [mul(v(d-delay),8)]=@switch 
     v(semaphore)=,{&d-state me=0;@emit The crowd cheers as the song runs down.},@notify me
-
&D-STARTVERSE Songkeg=5
-
&C-RESETKEG Songkeg=$resetkeg:@switch owner(%#)=owner(me),@tr me/s-resetkeg,@pemit 
     owner(%#)=Sorry, you cannot reset the [name(me)]. 
-
&D-STATE Songkeg=0
-
&C-SINGERR1 Songkeg=$kegsing *:@switch pos(//,%0)=#-1,@tr me/e-kegsing=%#
-
&C-SINGERR2 Songkeg=$kegsing:@tr me/e-kegsing=%#
-
&E-KEGSING Songkeg=@pemit owner(%0)=The correct format of that command is:%r%tKEGSING 
<line1>//<line2>. %rPlease type 'Use [name(me)]' for further details.
-
@Startup Songkeg=@drain me
-
&D-TIMER Songkeg=300
-
&F-DELAYMSG0 Songkeg=after [sub(v(d-startverse),v(semaphore))] more are submitted, 
     or in [v(d-timer)] seconds, whichever is sooner. 
-
&F-DELAYMSG-999 Songkeg=immediately.
-
@set Songkeg=SAFE
-
################################ End ##############################################